OMBALTER TIME_DIMENSION

Purpose

This command alter a time dimension.

Prerequisites

Should be in Oracle Module context.

Syntax

alterTimeDimensionCommand =  OMBALTER TIME_DIMENSION "TimeDimensionName" ( 
          ( "renameDimensionClause" [ "setPropertiesClause" ] | 
          "setPropertiesClause" ) | "setFiscalPropertyClause" | 
          "renameMapClause" | "useSequenceClause" | ( "addDimensionRoleClause" |
           DELETE ( "deleteDimensionRoleClause" | "deleteLevelClause" ) | MODIFY
           ( "modifyDimensionRoleClause" | "modifyLevelClause" ) )+ | ( { 
          "addCalendarHierarchyClause" | "modifyCalendarHierarchyClause" | 
          "addFiscalCalendarHierarchyClause" | 
          "modifyFiscalCalendarHierarchyClause" | "deleteHierarchyClause" } [ 
          "implementationClause" ] [ "populationClause" ] ) )
     TimeDimensionName =  "QUOTED_STRING"
     renameDimensionClause =  RENAME DIMENSION TO "QUOTED_STRING"
     setPropertiesClause =  SET PROPERTIES "propertyKeyList" VALUES 
          "propertyValueList"
     setFiscalPropertyClause =  "setFiscalPropertiesClause"
     renameMapClause =  RENAME MAPPING TO "QUOTED_STRING"
     useSequenceClause =  SET REF SEQUENCE "QUOTED_STRING"
     addDimensionRoleClause =  ADD DIMENSION_ROLE "roleName" [ 
          "setPropertiesClause" ]
     deleteDimensionRoleClause =  DIMENSION_ROLE "roleName"
     deleteLevelClause =  "levelLocator"
     modifyDimensionRoleClause =  DIMENSION_ROLE "roleName" RENAME TO "roleName"
           [ "setPropertiesClause" ]
     modifyLevelClause =  "levelLocator" ( "renameClause" [ 
          "setPropertiesClause" ] )
     addCalendarHierarchyClause =  ADD ( ( NORMAL_CALENDAR HIERARCHY 
          "hierarchyName" [ "setPropertiesClause" ] SET ( REF | REFERENCE ) 
          "normalCalendarLevelList" ) | ( WEEK_CALENDAR HIERARCHY 
          "hierarchyName" [ "setPropertiesClause" ] SET ( REF | REFERENCE ) 
          "weekCalendarLevelList" ) )
     modifyCalendarHierarchyClause =  MODIFY ( ( NORMAL_CALENDAR 
          "hierarchyLocator" ( [ "renameClause" ] [ "setPropertiesClause" ] SET 
          ( REF | REFERENCE ) "normalCalendarLevelList" ) ) | ( WEEK_CALENDAR 
          "hierarchyLocator" [ "renameClause" ] [ "setPropertiesClause" ] SET ( 
          REF | REFERENCE ) "weekCalendarLevelList" ) )
     addFiscalCalendarHierarchyClause =  ADD FISCAL_CALENDAR HIERARCHY 
          "hierarchyName" [ "setPropertiesClause" ] SET ( REF | REFERENCE ) 
          "fiscalCalendarLevelList"
     modifyFiscalCalendarHierarchyClause =  MODIFY FISCAL_CALENDAR 
          "hierarchyLocator" [ "renameClause" ] [ "setPropertiesClause" ] SET ( 
          REF | REFERENCE ) "fiscalCalendarLevelList"
     deleteHierarchyClause =  DELETE "hierarchyLocator"
     implementationClause =  IMPLEMENTED BY ( STAR | SNOWFLAKE ) [ USING 
          COMPOSITE_UNIQUE_KEY ]
     populationClause =  POPULATE DATA FROM "calendarYear" FOR "yearCount" YEARS
     propertyKeyList =  "(" "propertyKey" { "," "propertyKey" } ")"
     propertyValueList =  "(" "propertyValue" { "," "propertyValue" } ")"
     setFiscalPropertiesClause =  SET FISCAL_CALENDAR PROPERTIES 
          "propertyKeyList" VALUES "propertyValueList"
     roleName =  "QUOTED_STRING"
     levelLocator =  LEVEL "levelName"
     renameClause =  RENAME TO "QUOTED_STRING"
     hierarchyName =  "QUOTED_STRING"
     normalCalendarLevelList =  "(" ( "normalCalendarLevelType" LEVEL [ 
          "levelName" ] [ "setPropertiesClause" ] ) { "," 
          "normalCalendarLevelType" LEVEL [ "levelName" ] [ 
          "setPropertiesClause" ] } ")"
     weekCalendarLevelList =  "(" ( "weekCalendarLevelType" LEVEL [ "levelName" 
          ] [ "setPropertiesClause" ] ) { "," "weekCalendarLevelType" LEVEL [ 
          "levelName" ] [ "setPropertiesClause" ] } ")"
     hierarchyLocator =  HIERARCHY "hierarchyName"
     fiscalCalendarLevelList =  "(" ( "fiscalCalendarLevelType" LEVEL [ 
          "levelName" ] [ "setPropertiesClause" ] ) { "," 
          "fiscalCalendarLevelType" LEVEL [ "levelName" ] [ 
          "setPropertiesClause" ] } ")"
     calendarYear =  "INTEGER_LITERAL"
     yearCount =  "INTEGER_LITERAL"
     propertyKey =  "UNQUOTED_STRING"
     propertyValue =  ( "QUOTED_STRING" | "INTEGER_LITERAL" | 
          "FLOATING_POINT_LITERAL" )
     levelName =  "QUOTED_STRING"
     normalCalendarLevelType =  ( DAY | CALENDAR_MONTH | CALENDAR_QUARTER | 
          CALENDAR_YEAR )
     weekCalendarLevelType =  ( DAY | CALENDAR_WEEK )
     fiscalCalendarLevelType =  ( DAY | FISCAL_WEEK | FISCAL_MONTH | 
          FISCAL_QUARTER | FISCAL_YEAR )

Parameters

alterTimeDimensionCommand

This command alters time dimension.

TimeDimensionName

The name of the time dimension.

renameDimensionClause

This clause renames the time dimension.

setPropertiesClause

This clause sets the following properties:

Name: BUSINESS_NAME

Type: STRING(200)

Valid Values: Any valid character string in supported character set.

Default: Empty string

Name: DESCRIPTION

Type: STRING(4000)

Valid Values: Any valid character string in supported character set.

Default: Empty string

setFiscalPropertyClause

set the fiscal properties.

renameMapClause

This clause renames the map that is created by the OMBCREATE TIME_DIMENSION command.

useSequenceClause

This clause sets the Sequence.

addDimensionRoleClause

This clause adds a dimension role.

deleteDimensionRoleClause

This clause deletes a dimension role.

deleteLevelClause

This clause finds the level to be deleted.

modifyDimensionRoleClause

This clause allows to rename the dimension role, or it change the dimension role's properties.

modifyLevelClause

This clause modifies level by either renaming it, or setting level properties.

addCalendarHierarchyClause

This clause adds a new hierarchy to the time dimension by: renaming the hierarchy, setting of hierarchy properties, or setting level references.

modifyCalendarHierarchyClause

This clause modifies a hierarchy of the time dimension by: renaming the hierarchy, setting of hierarchy properties, or setting level references.

addFiscalCalendarHierarchyClause

This clause adds an fiscal hierarchy to the time dimension.

modifyFiscalCalendarHierarchyClause

This clause modifies a fiscal hierarchy of the time dimension by: renaming the fiscal hierarchy, setting of fiscal hierarchy properties, or setting fiscal level references.

deleteHierarchyClause

This clause deletes a hierarchy from time dimension.

implementationClause

Time Dimension is implemented as STAR or as SNOWFLAKE.

populationClause

This clause specifies the starting year and the number of years for which data will be populated.

propertyKeyList

A list of time dimension properties.

propertyValueList

A list of time dimension property values.

setFiscalPropertiesClause

This clause sets the following properties:

Fiscal types allowed in OWB time dimension. Name: FISCAL_TYPE

Type: STRING

Valid Values: '544', '445'

Default: '544'

Fiscal calendar year start date, it could be any date of a year.

Name: FISCAL_CALENDAR_START_YEAR

Type: STRING

Valid Values: Dates in these format 'DD-MON-YYYY' or 'DD-MM-YYYY'

Default: '01-JAN-2000'

The day of the week when the fiscal year begins.

Name: FISCAL_CALENDAR_START_DAY_OF_WEEK

Type: STRING

Valid Values: 'MONDAY', 'TUESDAY', 'WEDNESDAY', 'THURSDAY', 'FRIDAY', 'SATURDAY', 'SUNDAY'

Default: 'false'

roleName

A role name.

levelLocator

This clause gets the level.

renameClause

Renaming of the time dimension.

hierarchyName

The name of a hierarchy.

normalCalendarLevelList

List of Normal Calendar's Levels.

weekCalendarLevelList

List of Week Calendar Levels.

hierarchyLocator

This clause gets the hierarchy.

fiscalCalendarLevelList

This clause creates a fiscal hierarchy and sets reference fiscal levels.

calendarYear

Calendar year in INTEGER_LITERAL

yearCount

Year count in INTEGER_LITERAL

propertyKey

Property Key in UNQUOTED_STRING

propertyKey

Basic properties for TIME DIMENSION, TIME DIMENSION MAP, DIMENSION_ATTRIBUTE, LEVEL, LEVEL_ATTRIBUTE and HIERARCHY: 

Basic properties for TIME DIMENSION :
Name: BUSINESS_NAME
Type: STRING(200)
Valid Values: Any valid character string in supported character set.
Default: Empty string
Business name of the Time Dimension 

Name: DESCRIPTION
Type: STRING(4000)
Valid Values: Any valid character string in supported character set.
Default: Empty string
Description of the Time Dimension 

Name: STORAGE
Type: STRING
Valid Values: 'RELATIONAL', 'AW' 
Default: 'RELATIONAL' 
The storage of a dimension can be AW or relational 

Name: AW_NAME
Type: STRING(32)
Valid Values: Any valid character string in supported character set.
Default: Empty string
Set the analytical workspace name where the dimension is implemented 

Name: AW_DIMENSION_NAME
Type: STRING(32)
Valid Values: Any valid character string in supported character set.
Default: Empty string
Set the Analytical Workspace dimension physical object name 


Basic properties for TIME MAP :
Name: BUSINESS_NAME
Type: STRING(200)
Valid Values: Any valid character string in supported character set.
Default: Empty string
Business name of the Time Dimension Map

Name: DESCRIPTION
Type: STRING(4000)
Valid Values: Any valid character string in supported character set.
Default: Empty string
Description of the Time Dimension Map

Basic properties for DIMENSION_ATTRIBUTE:
Name: BUSINESS_NAME
Type: STRING(200)
Valid Values: Any valid character string in supported character set.
Default: Empty string
Business name of the Dimension_Attribute 

Name: DESCRIPTION
Type: STRING(4000)
Valid Values: Any valid character string in supported character set.
Default: Empty string

propertyValue

Property Key Value in QUOTED_STRING, INTEGER_LITERAL, FLOATING_POINT_LITERAL

levelName

Level name in QUOTED_STRING

normalCalendarLevelType

Type of Normal Calendar Levels: DAY, CALENDAR_MONTH, CALENDAR_QUARTER, CALENDAR_YEAR

weekCalendarLevelType

Type of Week Calendar Levels: DAY, CALENDAR_WEEK

fiscalCalendarLevelType

Type of Fiscal Calendar Type: DAY, FISCAL_WEEK, FISCAL_MONTH, FISCAL_QUARTER, FISCAL_YEAR

DIMENSION Object

Table 4-63 DIMENSION Object

Property	Type	Choices	Min	Max	Default	Description
DEPLOYABLE	BOOLEAN	true, false	none	none	true	Warehouse Builder generates a set of scripts to create an object only for those object marked as Deployable = true
DEPLOYMENT_OPTIONS	STRING	DEPLOY_ALL, DEPLOY_DATA_OBJECTS_ONLY, DEPLOY_TO_CATALOG_ONLY	none	none	DEPLOY_DATA_OBJECTS_ONLY	Warehouse Builder generates a set of scripts for Dimension, they are DDL Scripts for Relational Dimensional or Scripts for ROLAP or or Scripts for AW.
ENABLE_MV_REFRESH	BOOLEAN	true, false	none	none	false	Enable MV Refresh
GENERATION_COMMENTS	STRING	none	none	none	empty string	Enter additional comments for the generated code.
MVCONSTRAINTS	STRING	, ENFORCED, TRUSTED	none	none	TRUSTED	MV Constraints
NEXTDATE	STRING	none	none	none	empty string	Refresh Next Date
REFRESH	STRING	, COMPLETE, FAST, FORCE	none	none	FORCE	Refresh Mode
REFRESH_ON	STRING	, DEMAND, ONDATE	none	none	DEMAND	Refresh On
STARTWITH	STRING	none	none	none	empty string	Refresh Start Date
VIEW_NAME	STRING(30)	none	none	none	empty string	Name of the view that is generated to hide the control rows on the dimension implementation table of a star schema. If this field is left blank, the view name will default to '<Name of Dimension>_v'
VISIBLE	BOOLEAN	true, false	none	none	true	The Dimension is visible to OLAP end user if value is set = true.

HIERARCHY Object

Table 4-64 HIERARCHY Object

Property	Type	Choices	Min	Max	Default	Description
HIERLOADLEVEL	STRING	none	none	none	empty string

OMBALTER TIME_DIMENSION

Purpose

Prerequisites

Syntax

Parameters

alterTimeDimensionCommand

TimeDimensionName

renameDimensionClause

setPropertiesClause

setFiscalPropertyClause

renameMapClause

useSequenceClause

addDimensionRoleClause

deleteDimensionRoleClause

deleteLevelClause

modifyDimensionRoleClause

modifyLevelClause

addCalendarHierarchyClause

modifyCalendarHierarchyClause

addFiscalCalendarHierarchyClause

modifyFiscalCalendarHierarchyClause

deleteHierarchyClause

implementationClause

populationClause

propertyKeyList

propertyValueList

setFiscalPropertiesClause

roleName

levelLocator

renameClause

hierarchyName

normalCalendarLevelList

weekCalendarLevelList

hierarchyLocator

fiscalCalendarLevelList

calendarYear

yearCount

propertyKey

propertyKey

propertyValue

levelName

normalCalendarLevelType

weekCalendarLevelType

fiscalCalendarLevelType

DIMENSION Object

HIERARCHY Object

See Also